(:
   file:    list_metadata_1var.xq
   date:    13-July-2010
   author:  Gary Lewis
   purpose: Lists all metadata for a single variable specified at run-time.
   usage:   Can be run from any location.
   example: zorba -e varName:="control" -f -q list_metadata_1var.xq -o list_metadata_control.xml -z indent=yes
:)

declare variable $varName external;

<results>
{
for $i in fn:doc("../xml/metadata/ipedsVars_metadata_codes.xml")/variables/var[@name = $varName]
let $name := $i/@name,
    $year := $i/@year,
    $j := fn:doc("../xml/metadata/ipedsVars_metadata.xml")/variables/var[@name = $name]/detail[@year = $year],
    $dataType := $j/@dataType,
    $fieldWidth := $j/@fieldWidth,
    $desc := $j/@description,
    $source := $j/@source
order by
    $year descending
return <var name="{$name}" year="{$year}" dataType="{$dataType}" fieldWidth="{$fieldWidth}" description="{$desc}" source="{$source}">
       {
       for $k in fn:doc("../xml/metadata/ipedsVars_metadata_codes.xml")/variables/var[@name = $name][@year = $year]/code
       let $value := if ($dataType = "N") then xs:integer($k/@value) else $k/@value,
           $label := $k/@label
       order by $value ascending
       return <code value="{$value}" label="{$label}" />
       }
       </var>

}
</results>