(:
   file:    list_metadata_1year.xq
   date:    01-September-2010
   author:  Gary Lewis
   purpose: Lists all metadata for a single year specified at run-time.
   usage:   Run from path where program is located.
   example: zorba -e year:="2008" -f -q list_metadata_1year.xq -o list_metadata_2008.xml -z indent=yes
:)

declare variable $year external;

<survey year="{$year}">
{
for $j in doc("../xml/metadata/ipedsVars_metadata.xml")/variables/var/detail[@year = $year]
let $name := $j/../@name,
    $dataType := $j/@dataType,
    $fieldWidth := $j/@fieldWidth,
    $desc := $j/@description
order by
    $name ascending
return <var name="{$name}" dataType="{$dataType}" fieldWidth="{$fieldWidth}" description="{$desc}">
       {
       for $k in doc("../xml/metadata/ipedsVars_metadata_codes.xml")/variables/var[@name = $name][@year = $year]/code
       let $value := $k/@value,
           $label := $k/@label
       order by 
           (if ($dataType = "N") then xs:integer($k/@value) else $k/@value) ascending
       return <code value="{$value}" label="{$label}" />
       }
       </var>
}
</survey>